'Get target host and credentials
Wscript.StdOut.Write "Please enter target host:"
strComputer = Wscript.StdIn.ReadLine 
strDomain = strComputer 
Wscript.StdOut.Write "Please enter your user name:"
strUser = Wscript.StdIn.ReadLine 
Set objPassword = CreateObject("ScriptPW.Password")
Wscript.StdOut.Write "Please enter your password:"
strPassword = objPassword.GetPassword()

'Create output file
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objTextFile = objFSO.CreateTextFile("software_updates_" + strComputer + ".tsv", True)

'Connect to remote system
Set objSWbemLocator = CreateObject("WbemScripting.SWbemLocator")
Set objSWbemServices = objSWbemLocator.ConnectServer _
    (strComputer, "root\cimv2", strUser, strPassword, "MS_409", "ntlmdomain:" + strDomain)

'Pull data from system
Set colItems = objSWbemServices.ExecQuery _
    ("SELECT * FROM Win32_QuickFixEngineering")

'Write categories to file
objTextFile.WriteLine "Hostname" & vbtab & _
"Description" & vbtab & _
"Fix Comments" & vbtab & _
"Install Date" & vbtab & "Hotfix ID" & vbtab & _
"Service Pack"

'Write values to file
For Each objSoftware in colItems
 objTextFile.WriteLine strComputer & vbtab & _
 Description & vbtab & _
 objSoftware.FixComments & vbtab & _
 objSoftware.InstalledOn & vbtab & _
 objSoftware.HotFixID & vbtab & _
 objSoftware.ServicePackInEffect
Next
objTextFile.Close